pfc_propertypopulate

pfcutil.pbl   >   pfc_u_tabpg_dwproperty_srvresize   >   pfc_propertypopulate

Name	Datatype
lb_registeredscale	boolean[]
li_cntall	integer
li_cntreg	integer
li_index	integer
li_rc	integer
li_registeredmovex	integer[]
li_registeredmovey	integer[]
li_registeredscalex	integer[]
li_registeredscaley	integer[]
li_row	integer
li_style	integer
li_upperall	integer
li_upperreg	integer
ls_allobjects	string[]
ls_method	string
ls_registeredobjects	string[]

event pfc_propertypopulate;call super::pfc_propertypopulate;//////////////////////////////////////////////////////////////////////////////
//
//	Function:  		pfc_properypopulate
//
//	Access:    		Public
//
//	Arguments:  	None
//
//	Returns:   		Integer
//   1 if it succeeds.
//	 -1 if an error occurs.
//
//	Description:  	
//	Populate the screen edit controls with the current service values.
//
//////////////////////////////////////////////////////////////////////////////
//
//	Revision History
//
//	Version
//	6.0   Initial version
//
//////////////////////////////////////////////////////////////////////////////
//
//	Copyright © 1996-1997 Sybase, Inc. and its subsidiaries.  All rights reserved.
//	Any distribution of the PowerBuilder Foundation Classes (PFC)
//	source code by other than Sybase, Inc. and its subsidiaries is prohibited.
//
//////////////////////////////////////////////////////////////////////////////

integer	li_upperall, li_upperreg
integer	li_cntall, li_cntreg
integer 	li_rc
integer	li_style
integer	li_index
integer	li_row
string	ls_allobjects[]
string	ls_registeredobjects[]
string	ls_method
boolean	lb_registeredscale[]
integer	li_registeredmovex[]
integer	li_registeredmovey[]
integer	li_registeredscalex[]
integer	li_registeredscaley[]

// Validate references.
If IsNull(idw_requestor) or Not IsValid(idw_requestor) Then
	Return -1
End If
If IsNull(idw_requestor.inv_resize) or Not IsValid(idw_requestor.inv_resize) Then
	Return -1
End If

// Make sure there are no rows.
dw_register.Reset()

// Get all the columns the calculator object could sevice.
li_rc = idw_requestor.inv_resize.of_GetRegisterable(ls_allobjects)
// Get all the registered columns.
li_rc = idw_requestor.inv_resize.of_GetRegistered(ls_registeredobjects, lb_registeredscale, &
	li_registeredmovex, li_registeredmovey, li_registeredscalex, li_registeredscaley)
// Add All of the columns and Select the Registered columns
li_upperall = UpperBound(ls_allobjects)
li_upperreg = UpperBound(ls_registeredobjects)
For li_cntall = 1 to li_upperall
	li_row = dw_register.InsertRow(0)
	If li_row > 0 Then
		// Initilize the new row (the dw object has other initial values).
		dw_register.object.objectname.primary[li_row] = ls_allobjects[li_cntall]
		// Determine if this is an registered column.
		For li_cntreg = 1 to li_upperreg
			If ls_allobjects[li_cntall] = ls_registeredobjects[li_cntreg] Then
				// This is a registered row.
				
				dw_register.object.register.primary[li_row] = 'Y'
				If lb_registeredscale[li_cntreg] Then ls_method = 'S' Else ls_method = 'P'
				dw_register.object.method.primary[li_row] = ls_method
				dw_register.object.movex.primary[li_row] = li_registeredmovex[li_cntreg]
				dw_register.object.movey.primary[li_row] = li_registeredmovey[li_cntreg]
				dw_register.object.scalex.primary[li_row] = li_registeredscalex[li_cntreg]
				dw_register.object.scaley.primary[li_row] = li_registeredscaley[li_cntreg]
				Exit
			End If
		Next
	End If
Next

Return 1

end event

Name	Owner
datawindow.insertrow	datawindow
datawindow.reset	datawindow
systemfunctions.isnull	systemfunctions
systemfunctions.isvalid	systemfunctions
systemfunctions.upperbound	systemfunctions
pfc_n_cst_dwsrv_resize.of_getregisterable	pfc_n_cst_dwsrv_resize
pfc_n_cst_dwsrv_resize.of_getregistered	pfc_n_cst_dwsrv_resize
pfc_u_tabpg_dwproperty_base.pfc_propertypopulate	pfc_u_tabpg_dwproperty_base

Full name
pfc_u_tabpg_dwproperty_srvresize