rbuttonup

pfcmain.pbl   >   pfc_u_rte   >   rbuttonup

Name	Datatype
lb_frame	boolean
lm_edit	m_edit
ls_selectedtext	string
lw_childparent	window
lw_frame	window
lw_parent	window
lw_sheet	window

event rbuttonup;//////////////////////////////////////////////////////////////////////////////
//
//	Event:  rbuttonup
//
//	Description:  Popup menu
//
//////////////////////////////////////////////////////////////////////////////
//	
//	Revision History
//
//	Version
//	5.0   Initial version
//
//////////////////////////////////////////////////////////////////////////////
//
//	Copyright © 1996-1997 Sybase, Inc. and its subsidiaries.  All rights reserved.
//	Any distribution of the PowerBuilder Foundation Classes (PFC)
//	source code by other than Sybase, Inc. and its subsidiaries is prohibited.
//
//////////////////////////////////////////////////////////////////////////////

boolean		lb_frame
string			ls_selectedtext
m_edit		lm_edit
window		lw_parent
window		lw_frame
window		lw_sheet
window		lw_childparent

if not ib_rmbmenu then
	return
end if

// Get the parent window.
this.of_GetParentWindow (lw_parent)
if IsValid (lw_parent) then
	// Get the MDI frame window if available
	lw_frame = lw_parent
	do while IsValid (lw_frame)
		if lw_frame.windowtype = mdi! or lw_frame.windowtype = mdihelp! then
			lb_frame = true
			exit
		else
			lw_frame = lw_frame.ParentWindow()
		end if
	loop
	
	if lb_frame then
		// If MDI frame window is available, use it as the reference point for the
		// popup menu for sheets (windows opened with OpenSheet function) or child windows
		if lw_parent.windowtype = child! then
			lw_parent = lw_frame
		else
			lw_sheet = lw_frame.GetFirstSheet()
			if IsValid (lw_sheet) then
				do
					// Use frame reference for popup menu if the parentwindow is a sheet
					if lw_sheet = lw_parent then
						lw_parent = lw_frame
						exit
					end if
					lw_sheet = lw_frame.GetNextSheet (lw_sheet)
				loop until IsNull(lw_sheet) Or not IsValid (lw_sheet)
			end if
		end if
	else
		// SDI application.  All windows except for child windows will use the parent
		// window of the control as the reference point for the popmenu
		if lw_parent.windowtype = child! then
			lw_childparent = lw_parent.ParentWindow()
			if IsValid (lw_childparent) then
				lw_parent = lw_childparent
			end if
		end if
	end if
else
	return
end if

lm_edit = create m_edit
lm_edit.of_SetParent (this)

ls_selectedtext = SelectedText()
if Len (ls_selectedtext) > 0 then
	lm_edit.m_edititem.m_cut.enabled = true
	lm_edit.m_edititem.m_copy.enabled = true
else
	lm_edit.m_edititem.m_cut.enabled = false
	lm_edit.m_edititem.m_copy.enabled = false
end if

lm_edit.m_edititem.m_paste.enabled = true
lm_edit.m_edititem.m_selectall.enabled = true

this.event pfc_prermbmenu (lm_edit)

lm_edit.m_edititem.PopMenu (lw_parent.PointerX() + 5, lw_parent.PointerY() + 10)

destroy lm_edit

end event

Name	Owner
menu.popmenu	menu
window.getfirstsheet	window
window.getnextsheet	window
window.parentwindow	window
window.pointerx	window
window.pointery	window
richtextedit.selectedtext	richtextedit
systemfunctions.isnull	systemfunctions
systemfunctions.isvalid	systemfunctions
systemfunctions.len	systemfunctions
pfc_m_edit.of_setparent	pfc_m_edit
pfc_u_rte.of_getparentwindow	pfc_u_rte
pfc_u_rte.pfc_prermbmenu	pfc_u_rte

Full name
pfc_m_edit
pfc_m_edit.m_edititem