rbuttonup


pfcmain.pbl   >   pfc_u_lv   >   rbuttonup   

Full name pfc_u_lv.rbuttonup
Access public
Extend of
Return value
Prototype event rbuttonup(unsignedlong,integer,integer)

Name Datatype
No Data

Name Datatype
lb_frame boolean
le_align alignment
li_index integer
li_rc integer
li_width integer
ls_label string
lw_childparent window
lw_frame window
lw_parent window
lw_sheet window

event rbuttonup;//////////////////////////////////////////////////////////////////////////////
//
//	Event:  rbuttonup
//
//	Description:	popup menu
//
//////////////////////////////////////////////////////////////////////////////
//	
//	Revision History
//
//	Version
//	5.0   Initial version
//
//////////////////////////////////////////////////////////////////////////////
//
//	Copyright © 1996-1997 Sybase, Inc. and its subsidiaries.  All rights reserved.
//	Any distribution of the PowerBuilder Foundation Classes (PFC)
//	source code by other than Sybase, Inc. and its subsidiaries is prohibited.
//
//////////////////////////////////////////////////////////////////////////////

boolean	lb_frame
integer	li_rc
integer	li_index
integer	li_width
string		ls_label
alignment	le_align
window		lw_parent
window		lw_frame
window		lw_sheet
window		lw_childparent

// Determine if RMB popup menu should occur
if not ib_rmbmenu or il_rightclicked > 0 then
	return 1
end if

// Determine parent window for PointerX, PointerY offset
this.of_GetParentWindow (lw_parent)
if IsValid (lw_parent) then
	// Get the MDI frame window if available
	lw_frame = lw_parent
	do while IsValid (lw_frame)
		if lw_frame.windowtype = mdi! or lw_frame.windowtype = mdihelp! then
			lb_frame = true
			exit
		else
			lw_frame = lw_frame.ParentWindow()
		end if
	loop
	
	if lb_frame then
		// If MDI frame window is available, use it as the reference point for the
		// popup menu for sheets (windows opened with OpenSheet function) or child windows
		if lw_parent.windowtype = child! then
			lw_parent = lw_frame
		else
			lw_sheet = lw_frame.GetFirstSheet()
			if IsValid (lw_sheet) then
				do
					// Use frame reference for popup menu if the parentwindow is a sheet
					if lw_sheet = lw_parent then
						lw_parent = lw_frame
						exit
					end if
					lw_sheet = lw_frame.GetNextSheet (lw_sheet)
				loop until IsNull(lw_sheet) Or not IsValid (lw_sheet)
			end if
		end if
	else
		// SDI application.  All windows except for child windows will use the parent
		// window of the control as the reference point for the popmenu
		if lw_parent.windowtype = child! then
			lw_childparent = lw_parent.ParentWindow()
			if IsValid (lw_childparent) then
				lw_parent = lw_childparent
			end if
		end if
	end if
else
	return 1
end if

// Create popup menu
if IsNull(im_view) Or not IsValid (im_view) then
	im_view = create m_view
	im_view.of_SetParent (this)
end if

// Set the values of the Arrange Items submenu
li_index = 1
li_rc = GetColumn (li_index, ls_label, le_align, li_width)
do while li_rc = 1
	if li_index >=1 and li_index <= 10 then
		im_view.m_viewitem.m_arrangeicons.item[li_index].text = "by " + ls_label
		im_view.m_viewitem.m_arrangeicons.item[li_index].microhelp = "Sorts items by " + ls_label
		im_view.m_viewitem.m_arrangeicons.item[li_index].visible = true
	end if
	li_index++
	li_rc = GetColumn (li_index, ls_label, le_align, li_width)
loop

// Determine if the Auto Arrange Icons item should be enabled
if this.view = ListViewLargeIcon! or this.view = ListViewSmallIcon! then
	im_view.m_viewitem.m_arrangeicons.m_autoarrange.enabled = true
	im_view.m_viewitem.m_arrangeicons.m_autoarrange.checked = this.autoarrange
else
	im_view.m_viewitem.m_arrangeicons.m_autoarrange.enabled = false
	im_view.m_viewitem.m_arrangeicons.m_autoarrange.checked = false
end if

this.event pfc_prermbmenu (im_view)

im_view.m_viewitem.PopMenu (lw_parent.PointerX() + 5, lw_parent.PointerY() + 10)

return 1

end event

     
Name Owner
No Data

     
Name Owner
menu.popmenu menu
window.getfirstsheet window
window.getnextsheet window
window.parentwindow window
window.pointerx window
window.pointery window
listview.getcolumn listview
systemfunctions.isnull systemfunctions
systemfunctions.isvalid systemfunctions
pfc_u_lv.of_getparentwindow pfc_u_lv
pfc_m_view.of_setparent pfc_m_view
pfc_u_lv.pfc_prermbmenu pfc_u_lv

     
Full name
pfc_m_view
pfc_m_view.m_viewitem
pfc_m_view.m_arrangeicons

     
Name Scope
No Data