of_deleteselected

pfcdwsrv.pbl   >   pfc_n_cst_dwsrv_rowmanager   >   of_deleteselected

Name	Datatype
li_confirm	integer
li_delete	integer
ll_deletedcount	long
ll_row	long
ll_selectedcount	long

public function long of_deleteselected ();//////////////////////////////////////////////////////////////////////////////
//
//	Function:  of_DeleteSelected
//
//	Access:  Public
//
//	Arguments:  none
//
//	Returns:  long
//	Number of rows deleted
//	-1 = error
//
//	Description:  
//	Deletes any rows that are selected
//
//////////////////////////////////////////////////////////////////////////////
//
//	Revision History
//
//	Version
//	5.0   Initial version
// 5.0.04 	Changed loop to find next Selected row.  The starting row will now
//			be based on the last selected row.
//
//////////////////////////////////////////////////////////////////////////////
//
//	Copyright © 1996-1997 Sybase, Inc. and its subsidiaries.  All rights reserved.
//	Any distribution of the PowerBuilder Foundation Classes (PFC)
//	source code by other than Sybase, Inc. and its subsidiaries is prohibited.
//
//////////////////////////////////////////////////////////////////////////////

integer	li_confirm = 1
integer	li_delete
long		ll_selectedcount
long		ll_row
long		ll_deletedcount

// Validate requestor DW
if IsNull(idw_requestor) Or not IsValid (idw_requestor) then
	return -1
end if

// Determine number of selected rows
ll_row = idw_requestor.GetSelectedRow (0)
do while ll_row > 0
	ll_selectedcount++
	ll_row = idw_requestor.GetSelectedRow (ll_row)
loop

// Confirm delete
if ib_confirmondelete then
	li_confirm = of_ConfirmDelete (ll_selectedcount)
end if

// Delete selected rows
if li_confirm = 1 then
	// Prevent redraw slowdown if multiple rows selected
	if ll_selectedcount > 1 then
		SetPointer (hourglass!)
		idw_requestor.SetRedraw (false)
	end if
	
	// Get the first selected row.
	ll_row = idw_requestor.GetSelectedRow (0)
	do while ll_row > 0
		li_delete = idw_requestor.DeleteRow (ll_row)
		if li_delete > 0 then
			ll_deletedcount++
		else
			exit
		end if
		ll_row = idw_requestor.GetSelectedRow (ll_row -1)
	loop
end if

// Turn redraw back on if multiple rows were deleted
if ll_selectedcount > 1 then
	idw_requestor.SetRedraw (true)
end if

return ll_deletedcount
end function

Name	Owner
pfc_n_cst_dwsrv_rowmanager.pfc_deleterow	pfc_n_cst_dwsrv_rowmanager

Name	Owner
dragobject.setredraw	dragobject
datawindow.deleterow	datawindow
datawindow.getselectedrow	datawindow
systemfunctions.isnull	systemfunctions
systemfunctions.isvalid	systemfunctions
systemfunctions.setpointer	systemfunctions
pfc_n_cst_dwsrv_rowmanager.of_confirmdelete	pfc_n_cst_dwsrv_rowmanager