of_getobjects

pfcdwsrv.pbl   >   pfc_n_cst_dwsrv   >   of_getobjects

Name	Datatype
li_Count	integer
li_Start	integer
li_Tab	integer
ls_ObjHolder	string
ls_ObjString	string

public function integer of_getobjects (ref string as_objlist[], string as_objtype, string as_band, boolean ab_visibleonly);//////////////////////////////////////////////////////////////////////////////
//
//	Function:  		of_GetObjects (FORMAT 2)
//
//	Access:    		Public
//
//	Arguments:
//   as_objlist[]:	A string array to hold objects (passed by reference)
//   as_objtype:  	The type of objects to get (* for all, others defined
//							by the object .TYPE attribute)
//   as_band:  		The dw band to get objects from (* for all) 
//							Valid bands: header, detail, footer, summary
//							header.#, trailer.#
//   ab_visibleonly: TRUE  - get only the visible objects,
//							 FALSE - get visible and non-visible objects
//
//	Returns:  		Integer
//   					The number of objects in the array
//
//	Description:	The following function will parse the list of objects 
//						contained in the datawindow control associated with this service,
//						returning their names into a string array passed by reference, 
//						and returning the number of names in the array as the return value 
//						of the function.
//
//////////////////////////////////////////////////////////////////////////////
//
//	Revision History
//
//	Version
//	5.0   Initial version
//
//////////////////////////////////////////////////////////////////////////////
//
//	Copyright © 1996-1997 Sybase, Inc. and its subsidiaries.  All rights reserved.
//	Any distribution of the PowerBuilder Foundation Classes (PFC)
//	source code by other than Sybase, Inc. and its subsidiaries is prohibited.
//
//////////////////////////////////////////////////////////////////////////////
string	ls_ObjString, ls_ObjHolder
integer	li_Start=1, li_Tab, li_Count=0

/* Get the Object String */
ls_ObjString = idw_Requestor.Describe("Datawindow.Objects")

/* Get the first tab position. */
li_Tab =  Pos(ls_ObjString, "~t", li_Start)
Do While li_Tab > 0
	ls_ObjHolder = Mid(ls_ObjString, li_Start, (li_Tab - li_Start))

	// Determine if object is the right type and in the right band
	If (idw_Requestor.Describe(ls_ObjHolder + ".type") = as_ObjType Or as_ObjType = "*") And &
		(idw_Requestor.Describe(ls_ObjHolder + ".band") = as_Band Or as_Band = "*") And &
		(idw_Requestor.Describe(ls_ObjHolder + ".visible") = "1" Or Not ab_VisibleOnly) Then
			li_Count ++
			as_ObjList[li_Count] = ls_ObjHolder
	End if

	/* Get the next tab position. */
	li_Start = li_Tab + 1
	li_Tab =  Pos(ls_ObjString, "~t", li_Start)
Loop 

// Check the last object
ls_ObjHolder = Mid(ls_ObjString, li_Start, Len(ls_ObjString))

// Determine if object is the right type and in the right band
If (idw_Requestor.Describe(ls_ObjHolder + ".type") = as_ObjType or as_ObjType = "*") And &
	(idw_Requestor.Describe(ls_ObjHolder + ".band") = as_Band or as_Band = "*") And &
	(idw_Requestor.Describe(ls_ObjHolder + ".visible") = "1" Or Not ab_VisibleOnly) Then
		li_Count ++
		as_ObjList[li_Count] = ls_ObjHolder
End if

Return li_Count
end function

Name	Owner
pfc_n_cst_dwsrv_filter.of_buildfilterattrib	pfc_n_cst_dwsrv_filter
pfc_n_cst_dwsrv_filter.of_getregisterable	pfc_n_cst_dwsrv_filter
pfc_n_cst_dwsrv_querymode.of_setquerycols	pfc_n_cst_dwsrv_querymode
pfc_n_cst_dwsrv.of_getobjects	pfc_n_cst_dwsrv
pfc_n_cst_dwsrv.of_modify	pfc_n_cst_dwsrv
pfc_n_cst_dwsrv.of_getwidth	pfc_n_cst_dwsrv
pfc_n_cst_dwsrv.of_describe	pfc_n_cst_dwsrv
pfc_n_cst_dwsrv_find.of_buildcolumnnames	pfc_n_cst_dwsrv_find
pfc_n_cst_dwsrv_sort.of_buildsortattrib	pfc_n_cst_dwsrv_sort
pfc_n_cst_dwsrv_sort.of_getregisterable	pfc_n_cst_dwsrv_sort
pfc_n_cst_dwsrv_report.of_prepprint	pfc_n_cst_dwsrv_report
pfc_n_cst_dwsrv_report.of_ShiftBand	pfc_n_cst_dwsrv_report
pfc_n_cst_dwsrv_report.of_SetFont	pfc_n_cst_dwsrv_report
pfc_n_cst_dwsrv_report.of_setborder	pfc_n_cst_dwsrv_report
pfc_n_cst_dwsrv_report.of_setcolor	pfc_n_cst_dwsrv_report
pfc_n_cst_dwsrv_reqcolumn.of_getregisterable	pfc_n_cst_dwsrv_reqcolumn
pfc_n_cst_dwsrv_resize.of_getregisterable	pfc_n_cst_dwsrv_resize
pfc_u_tabpg_dwproperty_buffers.dw_requestorview.pfc_propertyunprotect	dw_requestorview
pfc_u_tabpg_dwproperty_srvquerymode.pfc_propertypopulate	pfc_u_tabpg_dwproperty_srvquerymode
pfc_u_tabpg_dwproperty_status.dw_requestorview.pfc_propertyunprotect	dw_requestorview

Name	Owner
datawindow.describe	datawindow
systemfunctions.len	systemfunctions
systemfunctions.mid	systemfunctions
systemfunctions.pos	systemfunctions