pfc_postopen

pfcdwsrv.pbl   >   pfc_w_sortmulti   >   pfc_postopen

Name	Datatype
li_found	integer
li_i	integer
li_newrow	integer
li_num_cols	integer
li_numcols_sort	integer
li_rc	Integer
ls_display	string

event pfc_postopen;//////////////////////////////////////////////////////////////////////////////
//
//	Event:  pfc_postopen
//
//	Description:  Set up the datawindow with column names and previous sort.
//
//////////////////////////////////////////////////////////////////////////////
//	
//	Revision History
//
//	Version
//	5.0   Initial version
//
//////////////////////////////////////////////////////////////////////////////
//
//	Copyright © 1996-1997 Sybase, Inc. and its subsidiaries.  All rights reserved.
//	Any distribution of the PowerBuilder Foundation Classes (PFC)
//	source code by other than Sybase, Inc. and its subsidiaries is prohibited.
//
//////////////////////////////////////////////////////////////////////////////
integer 	li_num_cols, li_found, li_i
integer 	li_numcols_sort, li_newrow
Integer	li_rc
string 	ls_display

SetPointer ( HourGlass! ) 

// Turn off re-drawing until all done.
dw_sort.SetReDraw (FALSE)

// Get dddw reference.
dw_sort.GetChild ( "display_column", idwc_cols ) 

// Populate the dropdownlistbox with column names.
li_numcols_sort = UpperBound ( inv_sortattrib.is_sortcolumns ) 
FOR li_i = 1 to li_numcols_sort
	// Insert a new row
	li_newrow = idwc_cols.InsertRow ( 0 ) 
	// Populate the attributes for the column.	
	idwc_cols.SetItem ( li_newrow, "columnname", inv_sortattrib.is_sortcolumns[li_i] ) 
	idwc_cols.SetItem ( li_newrow, "display_column", inv_sortattrib.is_colnamedisplay[li_i] ) 
	IF inv_sortattrib.ib_usedisplay[li_i] THEN
		li_rc = idwc_cols.SetItem ( li_newrow, "use_display", "1" ) 
	ELSE
		li_rc = idwc_cols.SetItem ( li_newrow, "use_display", "0" ) 
	END IF 
NEXT

// Add rows for the current sort. One row for each column.
li_num_cols = UpperBound ( inv_sortattrib.is_origcolumns ) 
FOR li_i = 1 to li_num_cols
	li_found = idwc_cols.Find ( "columnname = '" + inv_sortattrib.is_origcolumns[li_i] + &
									    "'", 1, idwc_cols.RowCount () ) 
	IF li_found > 0 THEN
		// Insert a new row.
		li_newrow = dw_sort.InsertRow (0) 		
		// Set the column		
		ls_display = idwc_cols.GetItemString (li_found, "display_column" ) 
		li_rc = dw_sort.SetItem ( li_newrow, "display_column", ls_display ) 
		// Check the Asc/Desc sort order column		
		li_rc = dw_sort.SetItem ( li_newrow, "sort_order", inv_sortattrib.is_origorder[li_i] ) 
	END IF 
NEXT 

// Make sure there is at least one empty row.
If dw_sort.RowCount() = 0 Then
	// Insert a new row.
	li_newrow = dw_sort.InsertRow (0)
End If

// Turn off re-drawing until all done.
dw_sort.SetReDraw (TRUE)

end event

Name	Owner
dragobject.setredraw	dragobject
datawindow.getchild	datawindow
datawindow.insertrow	datawindow
datawindow.rowcount	datawindow
datawindow.setitem	datawindow
datawindowchild.find	datawindowchild
datawindowchild.getitemstring	datawindowchild
datawindowchild.insertrow	datawindowchild
datawindowchild.rowcount	datawindowchild
datawindowchild.setitem	datawindowchild
systemfunctions.setpointer	systemfunctions
systemfunctions.upperbound	systemfunctions

Full name
pfc_w_sortmulti