pfc_postopen

pfcdwsrv.pbl   >   pfc_w_sortdragdrop   >   pfc_postopen

Name	Datatype
li_found	Integer
li_i	Integer
li_newrow	Integer
li_orignumcols	Integer
li_rc	Integer
li_sortnumcols	Integer

event pfc_postopen;call super::pfc_postopen;//////////////////////////////////////////////////////////////////////////////
//
//	Event Name:  pfc_postopen
//
//	Description:  Populate the columnnames and previous sort string
//
//////////////////////////////////////////////////////////////////////////////
//	
//	Revision History
//
//	Version
//	5.0   Initial version
//
//////////////////////////////////////////////////////////////////////////////
//
//	Copyright © 1996-1997 Sybase, Inc. and its subsidiaries.  All rights reserved.
//	Any distribution of the PowerBuilder Foundation Classes (PFC)
//	source code by other than Sybase, Inc. and its subsidiaries is prohibited.
//
//////////////////////////////////////////////////////////////////////////////
Integer 	li_i, li_sortnumcols
Integer	li_orignumcols, li_found, li_newrow
Integer	li_rc

SetPointer ( HourGlass! ) 

// Turn off re-drawing until all done.
dw_sortcolumns.SetReDraw (FALSE)

// Populate the "dw_sortcolumns" datawindow with column names.
// Loop around all the columns.
li_sortnumcols = UpperBound(inv_sortattrib.is_sortcolumns)
FOR li_i = 1 to li_sortnumcols
	// Insert a new row
	li_newrow = dw_sortcolumns.InsertRow(0) 
	// Populate the attributes for the column.
	dw_sortcolumns.SetItem(li_newrow, "columnname", inv_sortattrib.is_sortcolumns[li_i])
	dw_sortcolumns.SetItem(li_newrow, "displayname", inv_sortattrib.is_colnamedisplay[li_i]) 
	IF inv_sortattrib.ib_usedisplay[li_i] THEN
		dw_sortcolumns.SetItem ( li_newrow, "use_display", "1" ) 
	ELSE
		dw_sortcolumns.SetItem ( li_newrow, "use_display", "0" ) 
	END IF 
NEXT

// Sort dw_sortcolumns.
dw_sortcolumns.SetSort("displayname A")
dw_sortcolumns.Sort() 

// Find the current sort columns (dw_sorted) and display them as selected.
li_orignumcols = UpperBound(inv_sortattrib.is_origcolumns) 
FOR li_i = 1 to li_orignumcols
	// Find the row on dw_sortcolumns
	li_found = dw_sortcolumns.Find ( "columnname = '" + inv_sortattrib.is_origcolumns[li_i] + &
												 "'", 1, dw_sortcolumns.RowCount() ) 
	IF li_found > 0 THEN
		// Move the row from dw_sortcolumns to dw_sorted.
		li_rc = dw_sortcolumns.RowsMove ( li_found, li_found, Primary!, &
					dw_sorted, dw_sorted.RowCount()+1, Primary! )
		
		// Check the Asc/Desc sort order column
		dw_sorted.SetItem ( li_i, "sort_order", inv_sortattrib.is_origorder[li_i] ) 
	END IF 
NEXT 

// Turn off re-drawing until all done.
dw_sortcolumns.SetReDraw (TRUE)
end event

Name	Owner
dragobject.setredraw	dragobject
datawindow.find	datawindow
datawindow.insertrow	datawindow
datawindow.rowcount	datawindow
datawindow.rowsmove	datawindow
datawindow.setitem	datawindow
datawindow.setsort	datawindow
datawindow.sort	datawindow
systemfunctions.setpointer	systemfunctions
systemfunctions.upperbound	systemfunctions
w_master.pfc_postopen	w_master

Full name
pfc_w_sortdragdrop